Buono ma se devi scrivere rettangoli, è utile una sub che si incarica di farlo, ignorando i valori fuori scala.
Nell'esempio puoi definire un'immagine larga alta come vuoi, considera che poi si parte da 0, le coordinate di un'immagine larga 277 vanno da 0 a 276.
La routine che traccia rettangoli pieni accetta le coordinate dell'angolo superiore sinistro e l'angolo inferiore destro di un rettangolo, la larghezza dell'immagine (estratta da .stride che include anche i caratteri di escape), l'altezza, il vettore che contiene l'immagine, e il colore del rettangolo.
Per darti l'idea della velocità di esecuzione ho aggiunto Stopwatch che uso per mostrare sulla barra del titolo i millisecondi impiegati per scrivere i bytes nel vettore.
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim sw As New Stopwatch
Dim larghezza As UInt16 = 5000 ' 0...4999, solo positivi
Dim altezza As UInt16 = 2500 ' 0...2499, solo positivi
Dim immagine As New Bitmap(larghezza, altezza, Imaging.PixelFormat.Format8bppIndexed)
' creo una palette con 256 livelli di grigio
Dim palette As Imaging.ColorPalette = immagine.Palette
For i = 0 To palette.Entries.Length - 1
palette.Entries(i) = Color.FromArgb(i, i, i)
Next i
' associo la palette creata alla bitmap 8bpp,
' i valori 0...255 ora corrispondono alla scala dal nero al bianco
immagine.Palette = palette
' blocco i bit della bitmap per poter lavorare direttamente su un vettore di bytes
Dim area As Rectangle = New Rectangle(0, 0, immagine.Width, immagine.Height)
Dim bmpData As Imaging.BitmapData = immagine.LockBits(area, Imaging.ImageLockMode.ReadWrite, immagine.PixelFormat)
' puntatore all'indirizzo di memoria del primo byte.
Dim ptr As IntPtr = bmpData.Scan0
' un vettore che conterrà tutti i bytes della bitmap.
Dim bytes As Integer = Math.Abs(bmpData.Stride) * immagine.Height ' calcolo dei bytes necessari
Dim colorValues(bytes - 1) As Byte
sw.Restart() ' avvio il conteggio del tempo
rettangolo(0, 0, 4999, 299, Math.Abs(bmpData.Stride), altezza, colorValues, 255) ' rettangolo bianco superiore
rettangolo(0, 300, 299, 2499, Math.Abs(bmpData.Stride), altezza, colorValues, 100) ' rettanglo grigioscuro sinistro
rettangolo(300, 300, 4999, 2499, Math.Abs(bmpData.Stride), altezza, colorValues, 200) ' rettangolo grigio
Me.Text = "Scrittura Bytes in: " & sw.ElapsedMilliseconds & "ms." ' mostro il tempo impiegato
' ripristino vettore su immagine
System.Runtime.InteropServices.Marshal.Copy(colorValues, 0, ptr, bytes)
immagine.UnlockBits(bmpData) ' sblocco bit
immagine.Save("prova8bpp.bmp", Imaging.ImageFormat.Bmp)
End Sub
Sub rettangolo(x1 As UInt16, y1 As UInt16, x2 As UInt16, y2 As UInt16, larghezza As UInt32, altezza As UInt16, vettore() As Byte, colore As Byte)
' limite valori
If x1 >= larghezza Then x1 = larghezza - 1
If x2 >= larghezza Then x2 = larghezza - 1
If y1 >= altezza Then y1 = altezza - 1
If y2 >= altezza Then y2 = altezza - 1
For colonna = x1 To x2
For riga = y1 To y2
Dim ind As UInt32 = colonna + riga * larghezza 'calcolo l'indice
vettore(ind) = colore
Next
Next
End Sub
End Class
Il programma traccia 3 rettangoli con tre livelli di grigio (per identificarli), naturalmente i rettangoli tracciati dopo, se occupano le coordinate dei rettangoli tracciati prima, li sovrascrivono.
Considerato che scrivi Bytes direttamente in memoria, in VB.Net hai la massima velocità, anche se non paragonabile a GDI+.
Carlo
