Ok, ho risolto.
Premetto che non so se sia il modo migliore di farlo, e che non era mio intento fornire il codice "pronto" ma spiegare come farlo, però ho dovuto fare un po' di prove e sono arrivato a questo frammento di codice funzionante. Ho cercato di commentare molto in modo da spiegare come funziona.
Prima di tutto serve una funzione che sostituisca solo la prima occorrenza in una stringa. Eccola (mettila nel tuo sorgente da qualche parte dove non crea problemi, magari nello stesso file fuori dal Sub che gestisce l'evento):
Public Function replaceFirst(text As String, search As String, replace As String) As String
Dim i As Integer = text.IndexOf(search) 'posizione del primo carattere della stringa da sostituire
If i < 0 Then Return text 'se non viene trovata l'occorrenza, restituisce la stringa invariata
Return text.Substring(0, i) + replace + text.Substring(i + search.Length) 'componiamo la stringa risultante concatenando la parte della stringa originale prima del frammento da sostituire, la stringa da sostituire, e la parte dopo
End Function
Credit: mi sono leggermente ispirato (ok, non poi così leggermente
, l'ho più che altro "tradotta"
a questa
stackoverflow.com/a/…
Poi, ecco qua la "soluzione" che ho implementato:
'Il contenuto formattato in HTML che vogliamo copiare nella clipboard:
Dim tabella As String = "<table border='1'><tr><td><b>riga1</b></td></tr><tr><i>riga2</i></tr></title>"
'inizializzo la stringa da mettere nella clipboard con l'header, per ora senza settare gli indici. Al loro posto metto degli zeri, in modo da fissare una lunghezza per la stringa
Dim a As String = "Version:0.9" + vbCrLf +"StartHTML:000000" + vbCrLf +"EndHTML:000000" + vbCrLf +"StartFragment:000000" + vbCrLf +"EndFragment:000000" + vbCrLf
'ora aggiungiamo alla stringa da copiare l'html necessario.
'ottengo la dimensione della stringa convertendo la stringa in un array di byte con la codifica UTF8 e leggendone la dimensione
Dim headerSize As Integer = Text.Encoding.UTF8.GetBytes(a).Length
a += tabella
'ottengo la dimensione della stringa convertendo la stringa in un array di byte con la codifica UTF8 e leggendone la dimensione
Dim totalSize As Integer = Text.Encoding.UTF8.GetBytes(a).Length
'l'HTML inizia appena dopo l'header e finisce alla fine della clipboard,
'quindi abbiamo l'indice di inizio in headerSize e quello di fine in totalSize.
'A questo punto posso sostituire gli zeri con i valori trovati, facendo attenzione che questi siano di esattamente 6 cifre come i 6 zeri
'(utilizzando padLeft sulla stringa la porto ad dimensione di 6 caratteri aggiungendo zeri a sinistra)
Dim inizio As String = headerSize.ToString().padLeft(6, "0")
Dim fine As String = totalSize.ToString().padLeft(6, "0")
'la prima occorrenza degli zeri (per StartHTML) la sostituisco con l'indice di inizio
a = replaceFirst(a, "000000", inizio)
'la seconda (EndHTML) con l'indice di fine
a = replaceFirst(a, "000000", fine)
'stessa cosa per StartFragment e EndFragment
a = replaceFirst(a, "000000", inizio)
a = replaceFirst(a, "000000", fine)
Clipboard.SetText(a, TextDataFormat.Html)
La principale modifica che dovresti fare, ovviamente, è mettere al posto della stringa tabella i tuoi dati (come vedi nell'esempio ne ho messi alcuni a caso, giusto per provare la formattazione).
Come spiegato nei commenti il trucco sta nel mettere inizialmente degli zeri nell'header (ma in realtà porebbe essere qualsiasi altro carattere che in UTF8 ha una codifica in cui 1 char = 1 byte, come un'altra cifra o una lettera) per misurarne correttamente la lunghezza, e poi quando si conoscono i dati sostituirli al posto giusto.
Ho provato a farlo girare in una semplice applicazione console, poi ho incollato in Word e come previsto ho ottenuto la tabellina con la prima riga in grassetto e la seconda in corsivo. Immagino che su Outlook funzioni ugualmente (del resto a quanto ho capito questo formato per la clipboard è uno standard su Windows, inoltre immagino che i programmi Microsoft come quelli della suite Office gestiscano tutti il paste in HTML).
Una soluzione più elaborata e "seria", però in C# (da cui ho preso spunto), è spiegata qui
theartofdev.com/2014/06/12/setting-htmltext-to-clipboard-revisited/.
robypiro
